2 files changed, 66 insertions, 0 deletions
diff --git a/trinity-apps/koffice-i18n/koffice-i18n-9999.ebuild b/trinity-apps/koffice-i18n/koffice-i18n-9999.ebuild
new file mode 100644
index 00000000..e854e93a
--- /dev/null
+++ b/trinity-apps/koffice-i18n/koffice-i18n-9999.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Copyright 2021 The Trinity Desktop Project
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+TRINITY_MODULE_TYPE="applications"
+TRINITY_BUILD_ADMIN="yes"
+
+inherit trinity-base-2
+
+DESCRIPTION="TDE internationalization package for Koffice [Trinity]"
+HOMEPAGE="http://trinitydesktop.org/"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="${TRINITY_VER}"
+if [[ ${PV} != *9999* ]] ; then
+	KEYWORDS="~amd64 ~x86"
+fi
+IUSE=""
+
+TRINITY_LANGS="bg ca cs cy da de el en_GB es et eu fa fi
+		fr ga gl hu it ja km lv ms nb nds ne nl pl pt pt_BR
+		ru sk sl sr sr@Latn sv tr uk zh_CN zh_TW"
+
+for X in ${TRINITY_LANGS} ; do
+	IUSE="${IUSE} l10n_${X}"
+done
+
+DEPEND="
+	~trinity-base/tdelibs-${PV}
+"
+RDEPEND="$DEPEND"
+
+run_phase() {
+	local lang dir phase;
+	phase=${1}
+	lang=${2}
+
+	dir="koffice-i18n-${lang}"
+	pushd "${S}/${dir}" || die "No such dir: ${dir}"
+	trinity-base-2_${phase}
+	popd
+}
+
+src_prepare() {
+	trinity_l10n_for_each_locale_do run_phase src_prepare
+	eapply_user
+}
+
+src_configure() {
+	trinity_l10n_for_each_locale_do run_phase src_configure
+}
+
+src_compile() {
+	trinity_l10n_for_each_locale_do run_phase src_compile
+}
+
+src_install() {
+	trinity_l10n_for_each_locale_do run_phase src_install
+}
diff --git a/trinity-apps/koffice-i18n/metadata.xml b/trinity-apps/koffice-i18n/metadata.xml
new file mode 100644
index 00000000..7a38bb90
--- /dev/null
+++ b/trinity-apps/koffice-i18n/metadata.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<!-- maintainer-needed -->
+</pkgmetadata>