From bea4b1d209293af1e29d548438aa2947d9a2b25f Mon Sep 17 00:00:00 2001
From: "E. Liddell" <ejlddll@warpmail.net>
Date: Sun, 23 Feb 2020 17:02:25 -0500
Subject: stable ebuilds round 2--rebase and manifests

Signed-off-by: E. Liddell <ejlddll@warpmail.net>
---
 trinity-base/arts/Manifest           |  2 ++
 trinity-base/arts/arts-14.0.6.ebuild | 60 ++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100755 trinity-base/arts/Manifest
 create mode 100755 trinity-base/arts/arts-14.0.6.ebuild

(limited to 'trinity-base/arts')

diff --git a/trinity-base/arts/Manifest b/trinity-base/arts/Manifest
new file mode 100755
index 00000000..1d267102
--- /dev/null
+++ b/trinity-base/arts/Manifest
@@ -0,0 +1,2 @@
+DIST arts-trinity-14.0.6.tar.xz 680224 BLAKE2B d71c186e665f8e33c27edae86e94b38a1be592fdc5a842525540509290e1d15b781886dde82c4b749462aaa60c688e40e63d9d4a0d77043965d5d624cfa71402 SHA512 4870770cfcab1a6b677b8fb5baaea65dc973d4eff8a5c0defe3d0d0f3adb8cc2f8afdcc44700bea1490f4cee24e6d57e61d892a183b7aeff116cb22b5231ca35
+DIST arts-trinity-14.0.7.tar.xz 681500 BLAKE2B 7b5c5dfe9d5eb3ef39da630c28b15e3fdef8b6b099c3390bb00d70f6c31f803dfd5a739174a8d7c2d6038f633c9822bbd4a900f9f812d6bfffd0b63540121ec9 SHA512 d877a885d827d14a3080266e3572a6ec141deca371aec45796e59f66658d1288b75a47b3036ccfa70d1371cd80bc7161ed1b1816d9aa09a21a4b3f7a1295c9fa
diff --git a/trinity-base/arts/arts-14.0.6.ebuild b/trinity-base/arts/arts-14.0.6.ebuild
new file mode 100755
index 00000000..5b610638
--- /dev/null
+++ b/trinity-base/arts/arts-14.0.6.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Copyright 2020 The Trinity Desktop Project
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+EAPI="7"
+
+TRINITY_MODULE_TYPE="dependencies"
+TRINITY_MODULE_NAME="arts"
+
+inherit trinity-base-2
+
+set-trinityver
+
+DESCRIPTION="aRts, the Trinity sound (and all-around multimedia) server/output manager"
+HOMEPAGE="http://trinitydesktop.org/"
+LICENSE="|| ( GPL-2 GPL-3 )"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa -artswrappersuid jack mp3 vorbis"
+SLOT="${TRINITY_VER}"
+
+DEPEND="=dev-tqt/tqtinterface-${PV}
+	dev-libs/glib
+	media-libs/audiofile
+	mp3? ( media-libs/libmad )
+	alsa? ( media-libs/alsa-lib )
+	vorbis? ( media-libs/libogg media-libs/libvorbis )
+	jack? ( media-sound/jack-audio-connection-kit )"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	mycmakeargs=(
+		-DWITH_AUDIOFILE=ON
+		-DWITH_MAD="$(usex mp3)"
+		-DWITH_ALSA="$(usex alsa)"
+		-DWITH_VORBIS="$(usex vorbis)"
+		-DWITH_JACK="$(usex jack)"
+		-DWITH_ESOUND=OFF
+		-DWITH_SNDIO=OFF
+	)
+
+	trinity-base-2_src_configure
+}
+
+src_install() {
+	trinity-base-2_src_install
+
+	# Used for realtime priority, but off by default as it is a security hazard
+	use artswrappersuid && chmod u+s "${D}/${TDEDIR}/bin/artswrapper"
+}
+
+pkg_postinst() {
+	if ! use artswrappersuid ; then
+		elog "Run chmod u+s ${TDEDIR}/bin/artswrapper to let artsd use realtime"
+		elog "priority and so avoid possible skips in sound. However, on untrusted systems"
+		elog "this creates the possibility of a DoS attack that'll use 100% cpu at realtime"
+		elog "priority, and so is off by default. See Gentoo bug #7883."
+		elog "Or, you can set the artswrappersuid USE flag to make the ebuild do this."
+	fi
+}
-- 
cgit v1.2.1