From 9f59a1d0c834bc706d6e74f0a0dc9f026e935b41 Mon Sep 17 00:00:00 2001
From: ormorph <roma251078@mail.ru>
Date: Mon, 15 Nov 2021 22:06:35 +0300
Subject: Added ebuilds for stable version 14.0.11

Signed-off-by: ormorph <roma251078@mail.ru>
---
 trinity-base/tdm/Manifest           |   1 +
 trinity-base/tdm/tdm-14.0.11.ebuild | 111 ++++++++++++++++++++++++++++++++++++
 2 files changed, 112 insertions(+)
 create mode 100644 trinity-base/tdm/tdm-14.0.11.ebuild

(limited to 'trinity-base/tdm')

diff --git a/trinity-base/tdm/Manifest b/trinity-base/tdm/Manifest
index 36fd9633..fc5248d9 100644
--- a/trinity-base/tdm/Manifest
+++ b/trinity-base/tdm/Manifest
@@ -1 +1,2 @@
+DIST tdebase-trinity-14.0.11.tar.xz 30554508 BLAKE2B f276a566f5cfd2ab66969209bdb0b273ce690c6ad6f12e869440e69f86ff7a6dc638aee6f2057c063796f87a30021896d152ebbcfb3f6b10958d0b759cff88dd SHA512 bd2894d07d8e03cc14f4ef0d99661aeb02d5a7b112ef007e758c926431587bfa9595ab477ec79c87ba2b5c5af36dfb3cd665faaa04a75f16eeab27a115874b1e
 DIST tdebase-trinity-14.0.8.tar.xz 30049464 BLAKE2B c5a9a9c79cc12c8a9e85fb1913f334a208609c452fe150ade62bee5798e61abd956512f10059c215e7f7e07182dfbc1f3017600466598f85d9137689a7d0126e SHA512 e52ed05b416bb29b4a8d742bdcd908f5887d06aa7a64d2a1218a603a0926098504c0f1ef6de41552070ce1e5e32219156bb8c5fc4f47f9819efe3e02145de403
diff --git a/trinity-base/tdm/tdm-14.0.11.ebuild b/trinity-base/tdm/tdm-14.0.11.ebuild
new file mode 100644
index 00000000..50ee7469
--- /dev/null
+++ b/trinity-base/tdm/tdm-14.0.11.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2021 Gentoo Authors
+# Copyright 2021 The Trinity Desktop Project
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+TRINITY_MODULE_NAME="tdebase"
+TRINITY_MODULE_TYPE="core"
+TSM_EXTRACT_ALSO="translations/"
+inherit trinity-meta-2
+
+DESCRIPTION="Trinity login manager, similar to XDM and GDM"
+if [[ ${PV} != *9999* ]] ; then
+    KEYWORDS="~amd64 ~x86"
+fi
+IUSE="+hwlib pam sak +svg xcomposite xdmcp +xrandr"
+
+DEPEND="
+	sys-apps/dbus
+	~trinity-base/kcontrol-${PV}
+	~trinity-base/tdelibs-${PV}[xrandr?]
+	x11-libs/libXtst
+	pam? ( trinity-base/tdebase-pam )
+	svg? ( media-libs/libart_lgpl )
+	xcomposite? ( x11-libs/libXcomposite )
+	xdmcp? ( x11-libs/libXdmcp )
+"
+RDEPEND="${DEPEND}
+	~trinity-base/tdepasswd-${PV}
+	x11-apps/xinit
+	x11-apps/xmessage"
+
+pkg_setup() {
+	trinity-meta-2_pkg_setup
+	use sak && TRINITY_SUBMODULE+=" tsak"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_XTEST=ON
+		-DWITH_SHADOW=ON
+		-DWITH_LIBART="$(usex svg)"
+		-DWITH_XCOMPOSITE="$(usex xcomposite)"
+		-DWITH_XDMCP="$(usex xdmcp)"
+		-DWITH_XRANDR="$(usex xrandr)"
+		-DWITH_TDEHWLIB="$(usex hwlib)"
+		-DWITH_PAM="$(usex pam)"
+		-DTDM_PAM_SERVICE=tde
+	)
+
+	trinity-meta-2_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# Customize the tdmrc configuration
+	sed -i -e "s:#SessionsDirs=:SessionsDirs=/usr/share/xsessions\n#SessionsDirs=:" \
+		"${D}/${TDEDIR}/share/config/tdm/tdmrc" || die "sed tdmrc failed"
+
+	# Install XSession upstream script seems to be debian-cpecific
+	cp "${FILESDIR}/${PN}-14.0.8-xsession.script" "${D}/${TDEDIR}/share/config/tdm/Xsession" || die
+	sed -i -e "s!@TRINITY_INSTALL_PATH@!${TDEDIR}!" "${D}/${TDEDIR}/share/config/tdm/Xsession" \
+		|| die "sed tdmrc failed"
+}
+
+pkg_postinst() {
+	# Set the default TDM face icon if it's not already set by the system admin
+	# because this is user-overrideable in that way, it's not in src_install
+	if [[ ! -e "${ROOT}${TDEDIR}/share/apps/tdm/faces/.default.face.icon" ]]; then
+		mkdir -p "${ROOT}${TDEDIR}/share/apps/tdm/faces" || die
+		cp "${ROOT}${TDEDIR}/share/apps/tdm/pics/users/default1.png" \
+			"${ROOT}${TDEDIR}/share/apps/tdm/faces/.default.face.icon" || die
+	fi
+	if [[ ! -e "${ROOT}${TDEDIR}/share/apps/tdm/faces/root.face.icon" ]]; then
+		mkdir -p "${ROOT}${TDEDIR}/share/apps/tdm/faces" || die
+		cp "${ROOT}${TDEDIR}/share/apps/tdm/pics/users/root1.png" \
+			"${ROOT}${TDEDIR}/share/apps/tdm/faces/root.face.icon" || die
+	fi
+
+	if use sak; then
+		sak_ok=yes
+		if ! linux_config_exists; then
+			ewarn "Can't check the linux kernel configuration."
+			ewarn "You might have some incompatible options enabled."
+			sak_ok=no
+		else
+			if ! linux_chkconfig_present INPUT_UINPUT; then
+				eerror "You have built tdm with the Secure Attention Key (SAK) feature enabled."
+				eerror "It requires INPUT_UINPUT support to be enabled in the kernel."
+				eerror "Please enable it:"
+				eerror "    CONFIG_INPUT_UINPUT=y"
+				eerror "in /usr/src/linux/.config or"
+				eerror "    Device Drivers --->"
+				eerror "        Input device support  --->"
+				eerror "           [*] Miscellaneous devices  --->"
+				eerror "                <*> User level driver support"
+				sak_ok=no
+			fi
+		fi
+		if [[ "$sak_ok" != yes ]]; then
+			sed -i -e 's:#\?\s*UseSAK=\(true\|false\)\?:UseSak=false:' \
+				"${D}${TDEDIR}/share/config/tdm/tdmrc" || die "sed tdmrc failed"
+			ewarn "SAK feature is disabled. You can enable it yourself by setting UseSAK=true"
+			ewarn "in ${TDEDIR}/share/config/tdm/tdmrc "
+		else
+			ewarn "SAK feature is enabled. You can disable it yourself by setting UseSAK=false"
+			ewarn "in ${TDEDIR}/share/config/tdm/tdmrc "
+		fi
+	fi
+}
-- 
cgit v1.2.1