From bea4b1d209293af1e29d548438aa2947d9a2b25f Mon Sep 17 00:00:00 2001
From: "E. Liddell" <ejlddll@warpmail.net>
Date: Sun, 23 Feb 2020 17:02:25 -0500
Subject: stable ebuilds round 2--rebase and manifests

Signed-off-by: E. Liddell <ejlddll@warpmail.net>
---
 trinity-base/tdm/Manifest          |   2 +
 trinity-base/tdm/tdm-14.0.6.ebuild | 107 +++++++++++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)
 create mode 100644 trinity-base/tdm/Manifest
 create mode 100644 trinity-base/tdm/tdm-14.0.6.ebuild

(limited to 'trinity-base/tdm')

diff --git a/trinity-base/tdm/Manifest b/trinity-base/tdm/Manifest
new file mode 100644
index 00000000..b2bbd5ea
--- /dev/null
+++ b/trinity-base/tdm/Manifest
@@ -0,0 +1,2 @@
+DIST tdebase-trinity-14.0.6.tar.xz 30023524 BLAKE2B 7be823f5e5d2555a7cbcf9ae08cfc5999e3d08da3ad4546ca357a228d37291bc6553f0ccda2924683f00db6c3dce59c42420858a48badad99e318488b5c1656e SHA512 ac49887ef407fd5290ca1cb95121ad7eac17d41a4be95caaa21f42559ab5904d93d152bdfd63d79f0d5e761653031a2c620fcb7bcec933dc97cf9307606bc14d
+DIST tdebase-trinity-14.0.7.tar.xz 30025772 BLAKE2B d163bb263ef0351dcf437777e7dbf5da4681baa2023cb2d53357145fec25a5ecb7015832645862b912b25b0d2f61432c6e4b740fad4c84b153610dc3be30c60a SHA512 ce9fbac0553b49c21061cf5cf22acf0831b6a2984ac08df3d37a1ed28ed1e7066cfc9cfb7fc3c78e40b876553dee6c3b1bd9e6fc5419af310645ac704a2abdb7
diff --git a/trinity-base/tdm/tdm-14.0.6.ebuild b/trinity-base/tdm/tdm-14.0.6.ebuild
new file mode 100644
index 00000000..7ab492fe
--- /dev/null
+++ b/trinity-base/tdm/tdm-14.0.6.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Copyright 2020 The Trinity Desktop Project
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+EAPI="7"
+TRINITY_MODULE_NAME="tdebase"
+
+inherit trinity-meta-2
+
+DESCRIPTION="Trinity login manager, similar to XDM and GDM"
+
+IUSE="pam xdmcp xcomposite sak +xrandr"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="pam? ( trinity-base/tdebase-pam )
+	xdmcp? ( x11-libs/libXdmcp )
+	xcomposite? ( x11-libs/libXcomposite )
+	xrandr? ( x11-libs/libXrandr )
+	=trinity-base/tdelibs-${PV}[xrandr?]
+	sys-apps/dbus
+	x11-libs/libXtst
+	=trinity-base/kcontrol-${PV}
+	=dev-libs/dbus-tqt-${PV}"
+
+RDEPEND="${DEPEND}
+	=trinity-base/tdepasswd-${PV}
+	x11-apps/xinit
+	x11-apps/xmessage"
+
+pkg_setup() {
+	trinity-meta-2_pkg_setup;
+	use sak && TRINITY_SUBMODULE+=" tsak"
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DWITH_XTEST=ON
+		-DWITH_LIBART=ON
+		-DWITH_SHADOW=ON
+		-DWITH_XCOMPOSITE="$(usex xcomposite)"
+		-DWITH_XDMCP="$(usex xdmcp)"
+		-DWITH_XRANDR="$(usex xrandr)"
+		-DWITH_PAM="$(usex pam)"
+		-DTDM_PAM_SERVICE=tde
+	)
+
+	trinity-meta-2_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# Customize the tdmrc configuration
+	sed -i -e "s:#SessionsDirs=:SessionsDirs=/usr/share/xsessions\n#SessionsDirs=:" \
+		"${D}/${TDEDIR}/share/config/tdm/tdmrc" || die "sed tdmrc failed"
+
+	# Install XSession upstream script seems to be debian-cpecific
+	cp "${FILESDIR}/${P}-xsession.script" "${D}/${TDEDIR}/share/config/tdm/Xsession"
+	sed -i -e "s!@TRINITY_INSTALL_PATH@!${TDEDIR}!" "${D}/${TDEDIR}/share/config/tdm/Xsession" \
+		|| die "sed tdmrc failed"
+}
+
+pkg_postinst() {
+	# Set the default TDM face icon if it's not already set by the system admin
+	# because this is user-overrideable in that way, it's not in src_install
+	if [ ! -e "${ROOT}${TDEDIR}/share/apps/tdm/faces/.default.face.icon" ];	then
+		mkdir -p "${ROOT}${TDEDIR}/share/apps/tdm/faces"
+		cp "${ROOT}${TDEDIR}/share/apps/tdm/pics/users/default1.png" \
+			"${ROOT}${TDEDIR}/share/apps/tdm/faces/.default.face.icon"
+	fi
+	if [ ! -e "${ROOT}${TDEDIR}/share/apps/tdm/faces/root.face.icon" ]; then
+		mkdir -p "${ROOT}${TDEDIR}/share/apps/tdm/faces"
+		cp "${ROOT}${TDEDIR}/share/apps/tdm/pics/users/root1.png" \
+			"${ROOT}${TDEDIR}/share/apps/tdm/faces/root.face.icon"
+	fi
+
+	if use sak; then
+		sak_ok=yes
+		if ! linux_config_exists; then
+			ewarn "Can't check the linux kernel configuration."
+			ewarn "You might have some incompatible options enabled."
+			sak_ok=no
+		else
+			if ! linux_chkconfig_present INPUT_UINPUT; then
+				eerror "You have built tdm with the Secure Attention Key (SAK) feature enabled. "
+				eerror "It requires INPUT_UINPUT support to be enabled in the kernel."
+				eerror "Please enable it:"
+				eerror "    CONFIG_INPUT_UINPUT=y"
+				eerror "in /usr/src/linux/.config or"
+				eerror "    Device Drivers --->"
+				eerror "        Input device support  --->"
+				eerror "           [*] Miscellaneous devices  --->"
+				eerror "                <*> User level driver support"
+				sak_ok=no
+			fi
+		fi
+		if [[ "$sak_ok" != yes ]]; then
+			sed -i -e 's:#\?\s*UseSAK=\(true\|false\)\?:UseSak=false:' \
+				"${D}${TDEDIR}/share/config/tdm/tdmrc" || die "sed tdmrc failed"
+			ewarn "SAK feature is disabled. You can enable it yourself by setting UseSAK=true "
+			ewarn "in ${TDEDIR}/share/config/tdm/tdmrc "
+		else
+			ewarn "SAK feature is enabled. You can disable it yourself by setting UseSAK=false"
+			ewarn "in ${TDEDIR}/share/config/tdm/tdmrc "
+		fi
+	fi
+}
-- 
cgit v1.2.1