AC_HAVE_GL
KDE_HAVE_GL=yes;
if test "X$GLLIB" = "X"; then
    KDE_HAVE_GL=no
fi

AC_SUBST(KDE_HAVE_GL)   

AC_ARG_WITH(
   threshold,
   [  --with-threshold@<:@=0..15@:>@  Smoke: TQt tests threshold Default:15 Lower=more tests],
   [ qt_test_threshold="$withval" ],
   [ qt_test_threshold=15 ]
)
AC_SUBST(qt_test_threshold)

if test "X$kde_build_libsmoke" = "Xtqt" -o "X$kde_build_libsmoke" = "Xtqt tde"; then

    AC_CONFIG_FILES([ smoke/tqt/qtguess.pl ], [
        cd smoke/tqt
        perl qtguess.pl
        cd ../..
    ])
    AC_CONFIG_FILES([ smoke/tqt/generate.pl ], [
    ])
fi

dnl -------
dnl Test for libqscintilla (TQScintilla support)
dnl -------

AC_ARG_ENABLE(
   qscintilla,
   [  --enable-qscintilla@<:@=yes|no@:>@   Smoke: build Smoke with TQScintilla extention for qt @<:@default:no@:>@],
   [ qtextscintilla="$enableval" ],
   [ qtextscintilla="no" ]
)
AC_SUBST(qtextscintilla)

AC_DEFUN([AC_FIND_QSCINTILLA],
[
AC_MSG_CHECKING([for libqscintilla])
AC_CACHE_VAL(ac_cv_lib_qscintilla,
[
 kde_ldflags_save="$LDFLAGS"
 kde_libs_save="$LIBS"
 kde_cxxflags_save="$CXXFLAGS"

 LIBS="-lqscintilla $LIBTQT $LIBS"
 CXXFLAGS="$CXXFLAGS $all_includes"
 LDFLAGS="$LDFLAGS $all_libraries $USER_LDFLAGS"

AC_TRY_LINK([
   #include <qextscintillabase.h>
],
[
            QextScintillaBase s;
],
            eval "ac_cv_lib_qscintilla='-lqscintilla'",
            eval "ac_cv_lib_qscintilla=no")

 LDFLAGS=$kde_ldflags_save
 LIBS=$kde_libs_save
 CXXFLAGS=$kde_cxxflags_save
])

if test ! "$ac_cv_lib_qscintilla" = no; then
  AC_DEFINE_UNQUOTED(HAVE_LIBTQSCINTILLA, 1, [Define if you have libqscintilla])
  LIBTQSCINTILLA="$ac_cv_lib_qscintilla"
  AC_MSG_RESULT($ac_cv_lib_qscintilla)
else
  AC_MSG_ERROR(not found. 
          Check your installation and look into config.log)
  LIBTQSCINTILLA=""
fi
AC_SUBST(LIBTQSCINTILLA)
])

if test "X$qtextscintilla" = "Xyes" ; then
  AC_FIND_QSCINTILLA
fi