1 files changed, 55 insertions, 0 deletions
diff --git a/kdvi/configure.in.in b/kdvi/configure.in.in
new file mode 100644
index 00000000..ba3ee342
--- /dev/null
+++ b/kdvi/configure.in.in
@@ -0,0 +1,55 @@
+
+dnl the following is just to fool the toplevel configure.in
+LTLIBOBJS=
+AC_SUBST(LTLIBOBJS)
+
+compile_kdvi=yes
+for j in $DO_NOT_COMPILE; do
+   if test "kdvi" = $j; then
+       compile_kdvi=no
+   fi
+done
+
+dnl AC_CONFIG_SUBDIRS has to be done before KDE_CREATE_SUBDIRSLIST
+if test "$compile_kdvi" = "yes"; then
+
+   KDE_FIND_PATH(kpsewhich, KPSEWHICH, [/usr/bin /bin /usr/sbin /opt/teTeX/bin /opt/local/bin /opt/bin /usr/local/bin], [ ])
+
+   have_kpsewhich=no
+   test_kpsewhich="`${KPSEWHICH-kpsewhich} -show-path cnf 2>/dev/null`"
+   test -n "${test_kpsewhich}" && have_kpsewhich=yes
+
+fi
+
+AC_CHECK_HEADERS(sys/types.h sys/params.h limits.h)
+
+# Check for freetype2
+KDE_FIND_PATH(freetype-config, FREETYPE_CONFIG, [${prefix}/bin ${exec_prefix}/bin /usr/local/bin /opt/local/bin],)
+
+if test -n "$FREETYPE_CONFIG"; then
+  vers=`$FREETYPE_CONFIG --version 2>/dev/null | awk 'BEGIN { FS = "."; } { printf "%d", ($1 * 1000 + $2) * 1000 + $3;}'`
+  if test -n "$vers" && test "$vers" -ge 8000002
+  then
+     LIBFREETYPE_LIBS="`$FREETYPE_CONFIG --libs`"
+     FREETYPE_RPATH=
+     for args in $LIBFREETYPE_LIBS; do
+	  case $args in
+	    -L*)
+  	       FREETYPE_RPATH="$FREETYPE_RPATH $args"
+ 	       ;;
+          esac
+     done
+     FREETYPE_RPATH=`echo $FREETYPE_RPATH | sed -e "s/-L/-R/g"`
+     LIBFREETYPE_CFLAGS="`$FREETYPE_CONFIG --cflags`"
+
+     AC_DEFINE_UNQUOTED(HAVE_FREETYPE, 1, [Defines if your system has the freetype library])
+  fi
+fi
+
+AC_SUBST(LIBFREETYPE_LIBS)
+AC_SUBST(LIBFREETYPE_CFLAGS)
+AC_SUBST(FREETYPE_RPATH)
+
+if test -z "$LIBFREETYPE_LIBS"; then
+	DO_NOT_COMPILE="$DO_NOT_COMPILE kdvi"
+fi