TEMPLATE	= app
TARGET		= tqmoc

CONFIG 		= console release qtinc yacc lex_included yacc_no_name_mangle
DEFINES	       += QT_MOC TQT_NO_CODECS QT_LITE_UNICODE TQT_NO_COMPONENT \
		  TQT_NO_STL TQT_NO_COMPRESS
win32:DEFINES  += QT_NODLL
DESTDIR         = ../../bin


INCLUDEPATH	+= $$QT_SOURCE_TREE/include ../tools .
DEPENDPATH	+= $$QT_SOURCE_TREE/include ../tools .
LIBS		=
OBJECTS_DIR	= .
SOURCES		= ../tools/qbuffer.cpp	    \
		  ../tools/tqptrcollection.cpp  \
		  ../tools/qcstring.cpp	    \
		  ../tools/qdatastream.cpp  \
		  ../tools/tqdatetime.cpp    \
		  ../tools/qfile.cpp	    \
		  ../tools/qdir.cpp	    \
		  ../tools/qfileinfo.cpp    \
		  ../tools/qgarray.cpp	    \
		  ../tools/qgdict.cpp	    \
		  ../tools/qglist.cpp	    \
		  ../tools/qglobal.cpp	    \
		  ../tools/qgvector.cpp	    \
		  ../tools/qiodevice.cpp    \
		  ../tools/qregexp.cpp	    \
		  ../tools/tqstring.cpp	    \
		  ../tools/qlocale.cpp	    \
                  ../tools/qunicodetables.cpp \
		  ../tools/tqstringlist.cpp  \
		  ../tools/tqtextstream.cpp  \
		  ../tools/qbitarray.cpp    \
		  ../tools/tqmap.cpp         \
		  ../tools/qgcache.cpp      \
		  ../codecs/tqtextcodec.cpp \
		  ../codecs/tqutfcodec.cpp

isEmpty(QT_PRODUCT)|contains(QT_PRODUCT, qt-internal) {
    LEXSOURCES  = moc.l
    YACCSOURCES = moc.y
} else {
    SOURCES   += moc_yacc.cpp
}

unix:SOURCES	+= ../tools/qfile_unix.cpp ../tools/qdir_unix.cpp ../tools/qfileinfo_unix.cpp
win32:SOURCES	+= ../tools/qfile_win.cpp ../tools/qdir_win.cpp ../tools/qfileinfo_win.cpp
macx:LIBS	+= -framework Carbon

target.path=$$bins.path
INSTALLS += target

*-mwerks {
   TEMPLATE = lib
   TARGET = McMoc
   CONFIG -= static
   CONFIG += shared plugin
   DEFINES += MOC_MWERKS_PLUGIN
   MWERKSDIR = $QT_SOURCE_TREE/util/mwerks_plugin
   INCLUDEPATH += $$MWERKSDIR/Headers
   LIBS += $$MWERKSDIR/Libraries/PluginLib4.shlb
   SOURCES += mwerks_mac.cpp
}