2 files changed, 86 insertions, 0 deletions
diff --git a/trinity-apps/k3b/Manifest b/trinity-apps/k3b/Manifest
index 67110a5e..a5f67340 100644
--- a/trinity-apps/k3b/Manifest
+++ b/trinity-apps/k3b/Manifest
@@ -1 +1,2 @@
 DIST k3b-trinity-14.1.0.tar.xz 3951192 BLAKE2B a9bf4c9751bbee91a4a889c917c05d38fed34dd1d99ad507c372c49e5f204275d4a58ab9e3bc0df002f1d470a7ce194ffe79493a6248e7373403505d4793776f SHA512 01ffd96cecf154d30d0216800dc6e0e40df6a2f32593098681d8af41e1b3c1c3c1bd2e2ab76442b4e2dbd75de0169faac9f064e29b3b74627d6515a01a5bcea2
+DIST k3b-trinity-14.1.1.tar.xz 3950736 BLAKE2B e6316477296acfed6d665e58b84e12b3e2b20f572579ec6bccdb92288745cf68edec80adc151143bca11f6d8a05a167bab5750a9d339e55351ae15f905aac29f SHA512 fd6117529c53848bf4bd9920c7b80b650a20a4ccb5e86d99b8462bbc652324f2d6ce9302408c9b4bb4cd82cb0ce8c744add66facfc103355bee218133dd62cfb
diff --git a/trinity-apps/k3b/k3b-14.1.1.ebuild b/trinity-apps/k3b/k3b-14.1.1.ebuild
new file mode 100644
index 00000000..62439774
--- /dev/null
+++ b/trinity-apps/k3b/k3b-14.1.1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2023 Gentoo Authors
+# Copyright 2020-2023 The Trinity Desktop Project
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+TRINITY_NEED_ARTS="optional"
+TRINITY_MODULE_TYPE="applications/multimedia"
+inherit trinity-base-2
+
+DESCRIPTION="A CD/DVD burning application for Trinity"
+HOMEPAGE="https://trinitydesktop.org/"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="14"
+if [[ ${PV} != *9999* ]] ; then
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+IUSE="alsa css dvd dvdr emovix encode debug ffmpeg ffmpeg_all_codecs flac
++handbook mp3 sndfile taglib vcd vorbis"
+
+DEPEND="
+	media-libs/libsamplerate
+	media-libs/taglib
+	media-sound/cdparanoia
+	alsa? ( media-libs/alsa-lib )
+	dvd? ( media-libs/libdvdread )
+	encode? ( media-sound/lame )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	flac? ( media-libs/flac[cxx] )
+	mp3? ( media-libs/libmad )
+	sndfile? ( media-libs/libsndfile )
+	vorbis? ( media-libs/libvorbis )
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	media-sound/normalize
+	app-cdr/cdrtools
+	css? ( media-libs/libdvdcss )
+	dvdr? ( app-cdr/dvd+rw-tools )
+	emovix? ( media-video/emovix )
+	encode? (
+		media-sound/sox
+		media-video/transcode[dvd]
+	)
+	vcd? ( media-video/vcdimager )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_HAL=OFF
+		-DWITH_SYSTEM_LIBSAMPLERATE=ON
+		-DWITH_MUSEPACK=OFF
+		-DWITH_MUSICBRAINZ=OFF
+		-DBUILD_K3BSETUP=OFF
+		-DBUILD_DOC="$(usex handbook)"
+		-DWITH_LIBDVDREAD="$(usex dvd)"
+		-DWITH_DEBUG="$(usex debug)"
+		-DWITH_ALSA="$(usex alsa)"
+		-DWITH_FFMPEG="$(usex ffmpeg)"
+		-DWITH_FFMPEG_ALL_CODECS="$(usex ffmpeg_all_codecs)"
+		-DWITH_FLAC="$(usex flac)"
+		-DWITH_SNDFILE="$(usex sndfile)"
+		-DWITH_TAGLIB="$(usex taglib)"
+		-DWITH_MAD="$(usex mp3)"
+		-DWITH_VORBIS="$(usex vorbis)"
+		-DWITH_LAME="$(usex encode)"
+	)
+
+	trinity-base-2_src_configure
+}
+
+pkg_postinst() {
+	echo
+	elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on the cdrom device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}