blob: ed5197093086008e5b2676b85f49a2fe5bc7aa52 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Contributor: e1z0 <justinas at eofnet dot lt>
_mod=amarok
_cat=applications/multimedia/
_kdemod="${_mod/tde/kde}"
pkgname="tde-${_mod}"
pkgver=14.1.2
pkgrel=1
pkgdesc="TDE Amarok"
arch=('i686' 'x86_64' 'aarch64' 'armv7h' 'powerpc64le')
url="https://scm.trinitydesktop.org/scm/git/${_mod}"
license=('GPL')
groups=('tde-extra')
depends=('tde-tdebase' 'taglib' 'xine-lib')
makedepends=('tde-cmake-trinity' 'tde-akode' 'ruby' 'libmtp' 'libvisual' 'sdl')
provides=("${_mod}")
conflicts=("trinity-${_mod}" "kdemod3-${_kdemod}")
replaces=("trinity-${_mod}")
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/${_cat}${_mod}-trinity-${pkgver}.tar.xz"
'bp000-add-taglib2-support-part2.diff')
md5sums=('f2c48a2061d9718cad303279f1e54922'
'7fe8fa72bbe23a685a5e4344b804f6c8')
install=''
[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity
prepare() {
msg "Apply backported patches"
cd ${srcdir}/${pkgname#*-}-trinity-${pkgver} || exit 1
patch -p1 < ${srcdir}/bp000-add-taglib2-support-part2.diff
}
build() {
msg "Creating out-of-source build directory: ${srcdir}/build"
mkdir -p ${srcdir}/build
cd ${srcdir}/build
export PKG_CONFIG_PATH=${TDEDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}
msg "Starting cmake..."
cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
-GNinja \
-DCMAKE_VERBOSE_MAKEFILE=ON \
-DCMAKE_INSTALL_PREFIX=${TDEDIR} \
-DBUILD_ALL=ON \
-DWITH_ALL_OPTIONS=ON \
-DWITH_YAUAP=OFF \
-DWITH_NJB=OFF \
-DWITH_IFP=OFF \
-DWITH_IPOD=OFF \
-DWITH_MP4V2=OFF \
-DWITH_EMBEDDED_SQLITE=ON \
-DWITH_SYSTEM_SQLITE=OFF \
-DWITH_MYSQL=OFF \
-DWITH_POSTGRESQL=OFF \
-DWITH_AMAZON=OFF
msg "Building - ${pkgname#*-}..."
ninja $NUMJOBS
}
package() {
msg "Packaging - $pkgname-$pkgver"
cd ${srcdir}/build
DESTDIR="${pkgdir}" ninja -j1 install
}
|
